==Mastermind clone for Chipmunk basic==

Un clon del famoso juego en el que el jugador debe acertar la contraseña de la computadora
Debería funcionar en [[chipmunk]] basic, y quizá en gwbasic.

<code gwbasic>
10 rem MASTERMIND CLONE
20 dim clave(5),turnos(25,2) : dim turn$(25)
30 dim cantidad(2,5)
40 for f = 0 to 5 : cantidad(1,f) = 0 : next f
50 for f = 1 to 5
60 clave(f) = rnd(5)
70 cantidad(1,clave(f)) = cantidad(1,clave(f))+1
80 next
90 turno = 0
100 bien = 0 : colocados = 0
110 input "Acierte la clave (5 cifras, de 0 a 4): ";a$
120 if len(a$) <> 5 then print "5 cifras, por favor." : goto 110
130 nonum = 0
140 for f = 0 to 5 : cantidad(2,f) = 0 : next f
150 for f = 1 to len(a$)
160 if mid$(a$,f,1) < "0" or mid$(a$,f,1) > "4" then nonum = -1 : goto 190
170 valor = val(mid$(a$,f,1))
180 if valor = clave(f) then colocados = colocados+1
185 cantidad(2,valor) = cantidad(2,valor)+1
190 next f
200 if nonum <> 0 then print "Cifras de 0 a 4, por favor." : goto 110
210 for f = 0 to 5
220 c = cantidad(2,f)
230 if cantidad(1,f) < c then c = cantidad(1,f)
240 bien = bien+c
250 next f
255 bien = bien-colocados
260 turnos(turno,1) = bien : turnos(turno,2) = colocados
270 turn$(turno) = a$
280 cls
285 print "CLAVE|ident|ubic|"
290 for f = 0 to turno
300 print turn$(f);"  "; : print using "###";turnos(f,1); : print using "###";turnos(f,2)
310 next f
320 turno = turno+1
330 if turno > 25 then print "Tardaste más de 25 turnos." : goto 360
340 if colocados = 5 then print "Descifraste la clave en";turno-1;"turnos. " : goto 360
350 goto 100
360 input "¿Desea volver a jugar? (S/N) ";r$
370 if r$ = "S" or r$ = "s" then goto 10
380 if r$ = "N" or r$ = "n" then end
390 goto 360
</code>